// Persistence of Vision Ray Tracer Scene Description File
// File: earth.pov
// Vers: 3.1
// Desc: Cloud covered Earth with Moon in background
// Date: Jan 28, 2001
// Auth: Michael Koopman (mkoopman@hotmail.com)
#include "colors.inc"
#include "textures.inc"
#declare clouds =
texture {
pigment {
bozo
turbulence 1.5
octaves 10
omega .5
lambda 2.5
color_map {
[0.0, 0.5 color rgbf<.75, .75, .75, 0>
color rgbf<.9, .9, .9, .9> ]
[0.5, 0.7 color rgbf<.9, .9, .9, .9>
color rgbf<1, 1, 1, 1> ]
[0.7, 1.0 color rgbf<1, 1, 1, 1>
color rgbf<1, 1, 1, 1> ]
}
}
}
background { rgb <0, 0, 0> }
camera {
location <0, 0, -12>
look_at <0, 0, 0>
}
light_source {
<25, 25, -25>
rgb <2, 2, 2>
}
sphere {
0, 1
scale 5
hollow
pigment {
image_map { png "EarthMap2.png" map_type 1 interpolate 2 }
rotate <18, 190, 0>
}
finish { phong 0.5 }
normal { bumps 0.1 scale 0.01 rotate y*360*clock }
}
sphere {
0, 1
scale 5.05
hollow
texture { clouds scale 3 rotate y*360*clock translate 2*clock }
}
sphere {
0, 1
scale 1
pigment {
image_map { png "MoonMap.png" map_type 1 interpolate 2 }
rotate <18, 190, 0>
}
translate <-8, 8, 8>
}